RGB Color Editor

createProgresBar(color, width, height, xAlign, yAlign, x, y) {
    Bar = self createBar(color, width, height);
    Bar setPoint(xAlign, yAlign, x, y);
    Bar thread destroyOnPlayerDeath(self);
    return Bar;
}
destroyOnPlayerDeath(player) {
    player waittill_any_return("death", "close_color_editor");
    self destroyElem();
    self destroy();
}
colorEditor(Element) {
    self endon("death");
    self.menuVariable["using_menu"] = false;
    wait 0.1;
    Bar[0] = self createProgresBar((1, 1, 1), 255, 20, "RIGHT", "CENTER", 100, 0);
    Bar[1] = self createProgresBar((1, 1, 1), 255, 20, "RIGHT", "CENTER", 100, 22);
    Bar[2] = self createProgresBar((1, 1, 1), 255, 20, "RIGHT", "CENTER", 100, 44);
    Title = self createFontString("objective", 2.0);
    Title setPoint("RIGHT", "CENTER", 100, -30);
    Title setText("Element: " + Element);
    Title.color = (0, 0, 0);
    Title thread destroyOnPlayerDeath(self);
    Marker = self createFontString("objective", 2.0);
    Marker setPoint("RIGHT", "CENTER", -165, 0);
    Marker setText("+");
    Marker thread destroyOnPlayerDeath(self);
    Instruct = self createFontString("objective", 1.7);
    Instruct setPoint("RIGHT", "CENTER", 100, 66);
    Instruct setText("[{+melee}] Down | [{+frag}]/[{+smoke}] change Value | [{+speed_throw}] Exit");
    Instruct thread destroyOnPlayerDeath(self);
    Value[0] = 0;
    Value[1] = 0;
    Value[2] = 0;
    self.isInColorEditor = true;
    self.currentBar = 0;
    self freezeControls(true);
    while (self.isInColorEditor) {
       if (self MeleeButtonPressed()) {
          self.currentBar++;
          if (self.currentBar >= Bar.size) self.currentBar = 0;
          Marker setPoint("RIGHT", "CENTER", -165, Bar[self.currentBar].y);
          wait 0.2;
       } else if (self FragButtonPressed()) {
          Value[self.currentBar]++;
          if (Value[self.currentBar] > 255) Value[self.currentBar] = 0;
          Bar[self.currentBar] updateBar(Value[self.currentBar] / 255);
       } else if (self SecondaryOffHandButtonPressed()) {
          Value[self.currentBar]--;
          if (Value[self.currentBar] < 0) Value[self.currentBar] = 255;
          Bar[self.currentBar] updateBar(Value[self.currentBar] / 255);
       } else if (self AdsButtonPressed()) {
          self.isInColorEditor = false;
       }
       wait 0.01;
       Title.color = (Value[0] / 255, Value[1] / 255, Value[2] / 255);
    }
    self freezeControls(false);
    self.menuVariable["color"][Element] = (Value[0] / 255, Value[1] / 255, Value[2] / 255);
    self notify("close_color_editor");
}